Error: Incorrect number of parameters for function 'IF()'. Expected 3, received 2

I would insist you try using a CASE like this:

CASE(
  Signatory_category__c, 
  "Service Provider", 
    IF(
      Staff_size_PSP__c > 200,
      "£7720 Staff greater than 200", 
      IF(
        Staff_size_PSP__c > 50, 
        "£5850 Staff 51 to 200", 
        IF(
          Staff_size_PSP__c > 25, 
          "£2700 Staff 26 to 50", 
          IF(
            Staff_size_PSP__c > 10, 
            "£780 11 to 25", 
            "£430 Staff less than 10"
          )
        )
      )
    ), 
  "Investment Manager", 
    IF(
      AUM__c > 50.00,  
      "£12500 IM AUM greater than 50", 
      IF(
        AUM__c > 29.99, 
        "£11000 IM AUM 30 to 50", 
        IF(
          AUM__c > 9.99,  
          "£10000 IM AUM 10 to 29.99", 
          IF(
            AUM__c > 4.99,  
            "£7000 IM AUM 5 to 9.99", 
            IF(
              AUM__c > 0.99,  
              "£4000 IM AUM 1 to 4.99", 
              IF (
                AUM__c > 0.099,  
                "£1500 IM AUM 0.1 to 0.99", 
                "£1000 IM AUM 0 to 0.1"
              )
            )
          )
        )
      )
    ), 
  "Asset Owner", 
    IF(
      AUM__c > 9.99, 
      "£7720 AO AUM greater than 10", 
      IF(
        AUM__c > 4.99,  
        "£5850 AO AUM 5 to 9.99", 
        IF(
          AUM__c > 0.99,  
          "£2700 AO AUM 1 to 4.99", 
          IF(
            AUM__c > 0.099, 
            "£780 AO AUM 0.1 to 0.99", 
            "£430 AO AUM 0 to 0.1"
          )
        )
      )
    ),
  NULL
)