I have a combination of 10 Picklist and number fields that need to be combined and into a formula field. All fields need to have a value, and if so, return "True".
I built a IF formula like below:
IF(
AND(
(TEXT( field1__c ) = "" ), <<THIS FOR PICKLIST FIELDS
ISBLANK( field2__c ) ), <<THIS FOR NUMBER FIELDS
"False", "True")
But it is not returning the right result. Looks like as soon as it finds one of the 10 fields filled, it returns "True".
What am I doing wrong?
답변 9개
Eric Praud (Activ8 Solar Energies) 
Forum Ambassador
Hi Sole,
Apologies, you need to change the AND to OR.
Try this then:
IF( NOT (
OR(
ISPICKVAL( Do_they_have_a_CISO__c , "" ) ,
ISBLANK( What_is_their_CISO_s_tenure_in_months__c ) ,
ISPICKVAL( Do_they_require_login__c , "" ),
ISPICKVAL( Do_they_have_a_VDP_program__c , "" ),
ISPICKVAL( Do_they_have_a_Bug_Bounty_program__c , "" ),
ISPICKVAL( Have_they_had_incidents__c , "" ),
ISBLANK( How_many_people_in_Security_team__c ) ,
ISBLANK( How_many_people_in_Engineering_team__c ),
ISBLANK( How_many_people_joined_in_the_last_year__c ) ,
ISBLANK( How_many_Security_jobs_are_opened__c )
)),
"True" , "False"
)
Now, if the formula is a checkbox, no need for the IF and true/false, you can simply write:
NOT (
OR(
ISPICKVAL( Do_they_have_a_CISO__c , "" ) ,
ISBLANK( What_is_their_CISO_s_tenure_in_months__c ) ,
ISPICKVAL( Do_they_require_login__c , "" ),
ISPICKVAL( Do_they_have_a_VDP_program__c , "" ),
ISPICKVAL( Do_they_have_a_Bug_Bounty_program__c , "" ),
ISPICKVAL( Have_they_had_incidents__c , "" ),
ISBLANK( How_many_people_in_Security_team__c ) ,
ISBLANK( How_many_people_in_Engineering_team__c ),
ISBLANK( How_many_people_joined_in_the_last_year__c ) ,
ISBLANK( How_many_Security_jobs_are_opened__c )
))
Also, make sure you select "Treat blank fields as blanks" at th ebottom of your formula
