Probar desencadenadores de Apex

Objetivos de aprendizaje

Después de completar esta unidad, podrá:

• Escribir una prueba para un desencadenador que se active en una operación con un solo registro.
  
• Ejecutar todos los métodos de una clase.
  

Nota

¿Su idioma de aprendizaje es español? Comience el reto en un Trailhead Playground en español y utilice las traducciones proporcionadas entre paréntesis para navegar. Copie y pegue solo los valores en inglés, ya que las validaciones del reto se basan en los datos en inglés. Si no aprueba el reto en su organización en español, le recomendamos que (1) cambie la configuración regional a Estados Unidos, (2) cambie el idioma a inglés, siga las instrucciones descritas aquí y, a continuación, (3) vuelva a hacer clic en el botón Check Challenge (Comprobar el reto).

Consulte la insignia Trailhead en su idioma para obtener más información sobre cómo aprovechar la experiencia de Trailhead en otros idiomas.

Probar desencadenadores de Apex

Antes de implementar un desencadenador, escriba pruebas de unidad que activen el desencadenador y compruebe si los resultados son los esperados.

Vamos a probar un desencadenador con el que hemos trabajado en el módulo Desencadenadores de Apex. Si un registro de cuenta tiene oportunidades relacionadas, el desencadenador AccountDeletion impide la eliminación del registro.

Requisitos previos

Si todavía no ha agregado el desencadenador AccountDeletion, siga estos pasos.

1. En Developer Console, seleccione File (Archivo) | New (Nuevo) | Apex Class (Clase de Apex).
   
2. Escriba AccountDeletion como el nombre del desencadenador y, a continuación, seleccione Account (Cuenta) para el sObject. Haga clic en Submit (Enviar).
   
3. Sustituya el código predeterminado por lo siguiente:
   

   trigger AccountDeletion on Account (before delete) {
     // Prevent the deletion of accounts if they have related opportunities.
     for(Account a : [SELECT Id FROM Account
       WHERE Id IN (SELECT AccountId FROM Opportunity) AND
       Id IN :Trigger.old]) {
       Trigger.oldMap.get(a.Id).addError('Cannot delete account with related opportunities.');
     }
   }

Si agregó el desencadenador AccountDeletion en una unidad anterior, pero lo desactivó para que el sistema pudiera comprobar su reto, vuelva a activarlo.

1. En Setup (Configuración), busque Apex Triggers (Desencadenadores de Apex).
   
2. En la página Apex Triggers (Desencadenadores de Apex), haga clic en Edit (Modificar) junto al desencadenador AccountDeletion.
   
3. Seleccione Is Active (Está activo).
   
4. Haga clic en Save (Guardar).
   

Si la organización tiene desencadenadores de una unidad anterior llamados AddRelatedRecord, CalloutTrigger o HelloWorldTrigger, desactívelos. Por ejemplo, para desactivar el desencadenador AddRelatedRecord:

1. En Setup (Configuración), busque Apex Triggers (Desencadenadores de Apex).
   
2. En la página Apex Triggers (Desencadenadores de Apex), haga clic en Edit (Modificar) junto al desencadenador AddRelatedRecord.
   
3. Anule la selección de Is Active (Está activo).
   
4. Haga clic en Save (Guardar).
   

Para desactivar los desencadenadores HelloWorldTrigger y CalloutTrigger, repita los pasos anteriores.

Agregar y ejecutar una prueba de unidad

Primero, vamos a empezar por agregar un método de prueba. Este método de prueba determina para qué se ha diseñado el desencadenador (caso positivo): impedir la eliminación de una cuenta si tiene oportunidades relacionadas.

1. En Developer Console, haga clic en File (Archivo) | New (Nuevo) | Apex Class (Clase de Apex).
   
2. Escriba TestAccountDeletion como el nombre de la clase y, a continuación, haga clic en OK (Aceptar).
   
3. Sustituya el cuerpo de clase predeterminado por el siguiente.
   

   @isTest
   private class TestAccountDeletion {
     @isTest
     static void TestDeleteAccountWithOneOpportunity() {
       // Test data setup
       // Create an account with an opportunity, and then try to delete it
       Account acct = new Account(Name='Test Account');
       insert acct;
       Opportunity opp = new Opportunity(
         Name=acct.Name + ' Opportunity',
         StageName='Prospecting',
         CloseDate=System.today().addMonths(1),
         AccountId=acct.Id);
       insert opp;
       // Perform test
       Test.startTest();
         Database.DeleteResult result = Database.delete(acct, false);
       Test.stopTest();
       // Verify
       // In this case the deletion should have been stopped by the trigger,
       // so verify that we got back an error.
       System.assert(!result.isSuccess());
       System.assert(result.getErrors().size() > 0);
       System.assertEquals('Cannot delete account with related opportunities.',
         result.getErrors()[0].getMessage());
     }
   }

   El método de prueba configura primero una cuenta de prueba con una oportunidad. A continuación, elimina la cuenta de prueba, lo que activa el desencadenador AccountDeletion. El método de prueba confirma si el desencadenador ha impedido la eliminación de la cuenta de prueba mediante la comprobación del valor devuelto de la llamada a Database.delete(). El valor devuelto es un objeto Database.DeleteResult que contiene información sobre la operación de eliminación. El método de prueba comprueba si la eliminación no se ha realizado correctamente y el mensaje de error que se obtiene.
   
4. Para ejecutar esta prueba, haga clic en Test (Prueba) | (New Run (Nueva ejecución).
   
5. En Test Classes (Clase de prueba), haga clic en TestAccountDeletion.
   
6. Para agregar todos los métodos de la clase TestAccountDeletion a la ejecución de prueba, haga clic en Add Selected (Agregar selección).
   
7. Haga clic en Run (Ejecutar). Busque el resultado de la prueba en la ficha Tests (Pruebas) debajo de la última ejecución.
   

La clase de prueba TestAccountDeletion contiene un solo método de prueba para probar un único registro de cuenta. Además, esta prueba es para el caso positivo. Pruebe siempre más casos para asegurarse de que el desencadenador funciona en todos los casos, como la eliminación de una cuenta sin oportunidades y las eliminaciones de cuentas masivas.

Los datos de prueba se configuran en el método de prueba, lo cual puede requerir mucho tiempo a medida que agrega métodos de prueba. Si tiene muchos métodos de prueba, incluya la creación de datos de prueba en una clase de utilidad de prueba y llame a la clase de utilidad desde varios métodos de prueba. En la unidad siguiente se explica cómo aprovechar una clase de utilidad de prueba y agregar métodos de prueba.

Más información

El método de prueba contiene el par de métodos Test.startTest() y Test.stopTest(), lo que delimita un bloque de código que obtiene un conjunto nuevo de límites regulados. En esta prueba, la configuración de los datos de prueba usa dos declaraciones DML para poder realizar la prueba. Para probar el código Apex con límites regulados, aísle el uso de límites de la configuración de datos de la prueba. Para aislar el uso de límites del proceso de configuración de datos, incluya la llamada a la prueba en el bloque Test.startTest() y Test.stopTest(). Use también este bloque de prueba para las pruebas de Apex asíncrono. Para obtener más información, consulte Uso de límites, startTest y stopTest.

Un problema conocido de Developer Console impide la actualización correcta de la cobertura de código al ejecutar un subconjunto de pruebas. Para actualizar todos los resultados de su cobertura de código, use Test (Prueba) | Run All (Ejecutar todo) en lugar de Test (Prueba) | New Run (Nueva ejecución).

Recursos

• Guía del desarrollador de Apex: Understanding Testing in Apex
  
• Guía del desarrollador de Apex: Triggers
  

Prepararse para el reto práctico

Para completar el reto práctico de esta unidad, deberá crear un desencadenador de Apex en el objeto Contact (Contacto) denominado RestrictContactByName con el siguiente código:

trigger RestrictContactByName on Contact (before insert, before update) {

  //check contacts prior to insert or update for invalid data

  for(Contact c : Trigger.New) {

    if(c.LastName == 'INVALIDNAME') {

      //invalidname is invalid

      c.AddError('The Last Name "'+c.LastName+'" is not allowed for DML');

    }

  }

}