유효성 검사 규칙 만들기
학습 목표
이 유닛을 완료하면 다음을 수행할 수 있습니다.
- 유효성 검사 규칙에 대한 두 가지 사용 사례를 설명할 수 있습니다.
- 유효성 검사 규칙의 요소를 나열할 수 있습니다.
- 유효성 검사 규칙을 만들 수 있습니다.
참고
한국어로 학습하시겠어요? Trailhead playground에서 한국어로 실습 과제를 시작하고, 괄호 안에 제공된 번역을 사용해 탐색해 보세요. 영어 데이터를 기반으로 실습 과제 검증이 이루어지므로 영문으로 표시된 값만 복사해 붙여 넣습니다. 한국어 조직에서 실습 과제를 통과하지 못한 경우, (1) 로캘을 미국을 바꾸고 (2) 여기에 제시된 지침에 따라 언어를 영어로 바꾼 후 (3) "Check Challenge(과제 확인)" 버튼을 눌러 다시 진행해 보세요.
원하는 언어로 Trailhead 사용하기 뱃지를 확인해 현지화된 Trailhead 경험을 활용하는 방법에 대해 자세히 알아보세요.
유효성 검사 규칙 소개
유효성 검사 규칙은 사용자가 레코드에 입력한 데이터가 저장하기 전에 지정한 표준을 충족하는지 확인합니다. 유효성 검사 규칙에는 하나 이상의 필드에서 데이터를 평가하고 'True' 또는 'False' 값을 반환하는 수식 또는 표현식이 포함될 수 있습니다. 유효성 검사 규칙이 'True' 값을 반환할 경우 사용자가 입력한 데이터에 잘못된 값이 포함되어 있음을 확인합니다. 유효성 검사 규칙에는 지정된 기준에 따라 잘못된 값을 입력할 때 사용자에게 표시할 오류 메시지도 포함될 수 있습니다. 이러한 규칙을 사용하면 데이터 품질을 효과적으로 개선할 수 있습니다. 예를 들어 모든 전화 번호 필드에 지정된 형식이 포함되거나 특정 제품에 적용되는 할인이 정의된 비율을 초과하지 않도록 할 수 있습니다.
유효성 검사 규칙 정의
개체, 필드, 캠페인 구성원 또는 사례 중대 사건에 대한 유효성 검사 규칙을 만들 수 있습니다. 이 단계에서는 사용자가 잘못된 길이의 계정 번호로 계정을 저장하려고 할 때 실행되는 유효성 검사 규칙을 만듭니다.
유효성 검사 규칙 만들기
- Setup(설정)에서 Object Manager(개체 관리자)로 이동하고 Account(계정)를 클릭합니다.
- 왼쪽 사이드바에서 Validation Rules(유효성 검사 규칙)를 클릭합니다.
-
New(새로 만들기)를 클릭합니다.
- 유효성 검사 규칙에 대해 다음 속성을 입력합니다.
- Rule Name(규칙 이름):
Account_Number_8_Characters - Error Condition Formula(오류 조건 수식):
LEN( AccountNumber) <> 8
- Rule Name(규칙 이름):
- 오류 메시지:
Account number must be 8 characters long.(계정 번호는 8자여야 합니다.) - 수식에 오류가 있는지 확인하려면 Check Syntax(구문 검사)를 클릭합니다.
-
Save(저장)를 클릭하여 작업을 마칩니다.
다음은 사용자가 필드에 잘못된 계정 번호 형식을 입력할 경우 유효성 검사 규칙의 오류 메시지가 나타나는 경우입니다.
유효성 검사 규칙 예
다음은 직접 시도해 볼 수 있는 몇 가지 유효성 검사 규칙 예입니다.
계정 번호 숫자 지정하기
AND 함수는 수식의 모든 값이 참일 경우 'True' 값을 반환하고 하나 이상의 값이 거짓이면 'False' 값을 반환합니다. ISBLANK 함수는 표현식에 값이 있는지 확인합니다. ISNUMBER 함수는 표현식의 값이 숫자인지 판별합니다. NOT 함수는 참이면 'FALSE'를, 거짓이면 'TRUE'를 반환합니다. 예에서 유효성 검사 규칙은 계정 번호가 비어 있지 않거나 숫자가 아닌지 확인합니다. 'True' 값은 사용자가 입력한 데이터에 잘못된 값이 포함되어 있음을 나타냅니다. 즉, 사용자가 계정 번호에 숫자가 아닌 값을 입력하면 유효성 검사 규칙이 'True' 응답을 반환하고 오류 메시지를 보냅니다.
Field(필드) |
Value(값) |
|---|---|
설명: |
Account Number(계정 번호)가 공백이 아닌 경우 숫자인지 확인합니다. |
수식: |
AND( NOT(ISBLANK(AccountNumber)), NOT(ISNUMBER(AccountNumber)) ) |
오류 메시지: |
계정 번호가 숫자가 아닙니다. |
오류 위치: |
계정 번호 |
날짜는 반드시 현재 연도로 지정하기
YEAR 함수는 지정된 날짜의 4자리 연도를 반환합니다. TODAY 함수는 현재 날짜를 반환합니다. <>(같지 않음) 연산자는 값이 다른 값과 같지 않은지 여부를 결정합니다. 예에서 유효성 검사 규칙은 지정된 날짜의 연도가 오늘 날짜의 연도와 같지 않은지 확인합니다. 'True' 값은 사용자가 입력한 데이터에 잘못된 값이 포함되어 있음을 나타냅니다. 즉, 사용자가 현재 연도가 아닌 날짜를 입력하면 유효성 검사 규칙이 'True' 응답을 반환하고 오류 메시지를 보냅니다.
Field(필드) |
Value(값) |
|---|---|
설명: |
사용자 정의 날짜 필드에 현재 연도 내의 날짜가 포함되어 있는지 확인합니다. |
수식: |
YEAR( My_Date__c ) <> YEAR ( TODAY() ) |
오류 메시지: |
날짜는 현재 연도여야 합니다. |
오류 위치: |
날짜 |
숫자 범위 유효성 검사
예에서 유효성 검사 규칙은 두 값(급여 최댓값 및 급여 최솟값) 간의 차이가 $20,000보다 큰지 확인합니다. 'True' 값은 사용자가 입력한 데이터에 잘못된 값이 포함되어 있음을 나타냅니다. 즉, 사용자가 차이가 $20,000 급여 범위를 초과하는 두 값을 입력하면 유효성 검사 규칙이 'True' 응답을 반환하고 오류 메시지를 보냅니다.
Field(필드) |
Value(값) |
|---|---|
설명: |
두 사용자 정의 필드 사이의 범위인 Salary Min(급여 최솟값)과 Salary Max(급여 최댓값)이 $20,000 이하입니다. |
수식: |
(Salary_Max__c - Salary_Min__c) > 20000 |
오류 메시지: |
급여 범위는 $20,000 이내여야 합니다. 급여 최댓값 또는 급여 최솟값을 조정합니다. |
오류 위치: |
급여 최댓값 |
웹 사이트 확장
AND 함수는 수식의 모든 값이 참일 경우 'True' 값을 반환하고 하나 이상의 값이 거짓이면 'False' 값을 반환합니다. <>(같지 않음) 연산자는 값이 다른 값과 같지 않은지 여부를 결정합니다. 예제에서 사용자가 유효한 확장자 6개 모두와 같지 않은 확장자를 가진 웹 사이트 URL을 입력할 경우 검증 규칙은 'True' 응답을 반환하고 오류 메시지를 보냅니다. 사용자가 유효한 확장자 중 하나와 동일한 확장자를 가진 웹 사이트 URL을 입력할 경우 검증 규칙은 사용자가 입력한 데이터가 유효하므로 'False' 응답을 반환하고 오류 메시지를 보내지 않습니다.
Field(필드) |
Value(값) |
|---|---|
설명: |
Web Site(웹 사이트)라는 사용자 정의 필드의 유효성을 검사하여 마지막 네 글자가 유효한 웹 사이트 확장의 명시적 집합에 있는지 확인합니다. |
수식: |
AND( RIGHT( Web_Site__c, 4) <> ".COM", RIGHT( Web_Site__c, 4) <> ".com", RIGHT( Web_Site__c, 4) <> ".ORG", RIGHT( Web_Site__c, 4) <> ".org", RIGHT( Web_Site__c, 4) <> ".NET", RIGHT( Web_Site__c, 4) <> ".net" ) |
오류 메시지: |
웹 사이트에는 .com, .org 또는 .net 확장자가 있어야 합니다. |
오류 위치: |
웹 사이트 |
유효한 청구지 국가
OR 함수는 수식의 하나 이상의 식이 참이면 'True' 응답을 반환하고 모든 식이 거짓이면 'False' 응답을 반환합니다. LEN 함수는 지정된 텍스트 문자열의 문자 수를 반환합니다. 이 예제에서 유효성 검사 규칙은 사용자가 청구지 국가 코드에 대해 입력한 값이 한 글자인지(필수 두 글자가 아님) 또는 유효한 두 글자 코드 중 하나를 포함하지 않는지 확인합니다. 이러한 조건 중 하나라도 참일 경우 유효성 검사 규칙은 'True' 값을 반환하고 오류 메시지를 보냅니다. 사용자가 유효한 청구 국가 코드를 입력하면 수식의 두 표현식은 모두 거짓입니다. LEN이 1이 아니고 데이터에 유효한 값 중 하나가 포함됩니다. 이 경우 유효성 검사 규칙은 'False' 값을 반환하고 오류 메시지를 보내지 않습니다.
Field(필드) |
Value(값) |
|---|---|
설명: |
Billing Country(청구지 국가) 계정이 유효한 ISO 3166 2자리 코드인지 확인합니다. |
수식: |
OR( LEN(BillingCountry) = 1, NOT( CONTAINS( "AF:AX:AL:DZ:AS:AD:AO:AI:AQ:AG:AR:AM:" & "AW:AU:AZ:BS:BH:BD:BB:BY:BE:BZ:BJ:BM:BT:BO:" & "BA:BW:BV:BR:IO:BN:BG:BF:BI:KH:CM:CA:CV:KY:" & "CF:TD:CL:CN:CX:CC:CO:KM:CG:CD:CK:CR:CI:HR:" & "CU:CY:CZ:DK:DJ:DM:DO:EC:EG:SV:GQ:ER:EE:ET:FK:" & "FO:FJ:FI:FR:GF:PF:TF:GA:GM:GE:DE:GH:GI:GR:GL:" & "GD:GP:GU:GT:GG:GN:GW:GY:HT:HM:VA:HN:HK:HU:" & "IS:IN:ID:IR:IQ:IE:IM:IL:IT:JM:JP:JE:JO:KZ:KE:KI:" & "KP:KR:KW:KG:LA:LV:LB:LS:LR:LY:LI:LT:LU:MO:MK:" & "MG:MW:MY:MV:ML:MT:MH:MQ:MR:MU:YT:MX:FM:MD:MC:" & "MC:MN:ME:MS:MA:MZ:MM:MA:NR:NP:NL:AN:NC:NZ:NI:" & "NE:NG:NU:NF:MP:NO:OM:PK:PW:PS:PA:PG:PY:PE:PH:" & "PN:PL:PT:PR:QA:RE:RO:RU:RW:SH:KN:LC:PM:VC:WS:" & "SM:ST:SA:SN:RS:SC:SL:SG:SK:SI:SB:SO:ZA:GS:ES:" & "LK:SD:SR:SJ:SZ:SE:CH:SY:TW:TJ:TZ:TH:TL:TG:TK:" & "TO:TT:TN:TR:TM:TC:TV:UG:UA:AE:GB:US:UM:UY:UZ:" & "VU:VE:VN:VG:VI:WF:EH:YE:ZM:ZW", BillingCountry))) |
오류 메시지: |
유효한 2자리 국가 코드가 필요합니다. |
오류 위치: |
청구지 국가 |
리소스
-
Salesforce 도움말: 유효성 검사 규칙
-
Salesforce 도움말: 유효성 검사 규칙 관리
-
Salesforce 도움말: 유효성 검사 규칙 작성을 위한 팁
-
Salesforce 도움말: 상황별 수식 연산과 함수