プラットフォームイベントの登録

学習の目的

この単元を完了すると、次のことができるようになります。

プラットフォームイベントメッセージの登録方法を説明する。
プラットフォーム上と外部アプリケーション内のイベントに登録する。
Apex テストメソッドでプラットフォームイベントをテストする。

メモ

日本語で受講されている方へChallenge は日本語の Trailhead Playground で開始し、かっこ内の翻訳を参照しながら進めていってください。Challenge での評価は英語データを対象に行われるため、英語の値のみをコピーして貼り付けるようにしてください。日本語の組織で Challenge が不合格だった場合は、(1) この手順に従って [Locale (地域)] を [United States (米国)] に切り替え、(2) [Language (言語)] を [English (英語)] に切り替えてから、(3) [Check Challenge (Challenge を確認)] ボタンをクリックしてみることをお勧めします。

翻訳版 Trailhead を活用する方法の詳細は、自分の言語の Trailhead バッジを参照してください。

プラットフォームイベントの公開方法は確認できましたが、プラットフォームイベントに登録して最新のニュースや荷物の配送の通知を受け取るにはどうすればよいのでしょうか? Salesforce Platform では、Apex トリガー、プロセス、フロー、empApi Lightning コンポーネントを使用してイベントに登録します。外部アプリケーションでは、Pub/Sub API を使用してイベントに登録します。

皆さんはおそらくすでに Apex トリガーを使用してデータベースイベントに基づくアクションを実行したことがあると思います。プラットフォームイベントでも、プロセスは似ています。受信イベントに登録するには、イベントオブジェクトに対する after insert トリガーを記述するだけです。トリガーは、Apex での自動登録メカニズムを提供します。チャネルの作成とリスンを明示的に行う必要はありません。トリガーは、Apex と API のどちらで公開されていても、さまざまなソースからイベント通知を受信します。

プラットフォームイベントは after insert トリガーのみをサポートします。after insert トリガーイベントは、プラットフォームイベントが公開された後のタイミングに対応します。イベントメッセージが公開されると、after insert トリガーが起動されます。

プラットフォームイベントトリガーを作成するには、開発者コンソールを使用します。

クイックアクセスメニュー () で [Developer Console (開発者コンソール)] を選択し、[File (ファイル)] | [New (新規)] | [Apex Trigger (Apex トリガー)] をクリックします。
名前を指定し、sObject のイベントを選択して [Submit (送信)] をクリックします。

開発者コンソールにより、トリガーテンプレートに after insert イベントが自動的に追加されます。さらに、[設定] のイベントの定義ページから [トリガー] 関連リストで簡単にトリガーを作成できますが、after insert キーワードを指定する必要があります。

次の例は、Cloud News イベントのトリガーを示します。各イベントを反復処理し、Urgent__c 項目でニュースが緊急かどうか確認します。ニュースが緊急の場合、トリガーはケースを作成して、ニュースレポーターを派遣し、イベントの場所をケースの件名に追加します。

この例を実行する前に、キューを作成し、表示ラベルを「Regional Dispatch」 (地域派遣) に設定します。キューを設定する方法については、Salesforce ヘルプの「キューの設定」を参照してください。キューを表す Group オブジェクトについての詳細は、『Salesforce および Lightning プラットフォームのオブジェクトリファレンス』の「Group」を参照してください。

この例では、ケースをキューに割り当てます。キューはプラットフォームイベントに含まれておらず、プラットフォームイベントを使用するためにキューを使用する必要はありません。ケースをキューに割り当てると、キューのメンバーであるサポートエージェントのチームにケースを振り分けられるようになります。

// Trigger for listening to Cloud_News events.
trigger CloudNewsTrigger on Cloud_News__e (after insert) {
    // List to hold all cases to be created.
    List<Case> cases = new List<Case>();
    // Get queue Id for case owner
    Group queue = [SELECT Id FROM Group WHERE Name='Regional Dispatch' AND Type='Queue'];
    // Iterate through each notification.
    for (Cloud_News__e event : Trigger.New) {
        if (event.Urgent__c == true) {
            // Create Case to dispatch new team.
            Case cs = new Case();
            cs.Priority = 'High';
            cs.Subject = 'News team dispatch to ' +
                event.Location__c;
            cs.OwnerId = queue.Id;
            cases.add(cs);
        }
   }
    // Insert all cases corresponding to events received.
    insert cases;
}

デバッグログの設定

標準またはカスタムオブジェクトのトリガーとは異なり、プラットフォームイベントのトリガーは、イベントを公開した Apex トランザクションと同じトランザクションでは実行されません。トリガーは、システムユーザーである自動化プロセスエンティティの下の独自プロセスで実行されます。そのため、トリガー実行に対応するデバッグログは自動化プロセスエンティティによって作成され、開発者コンソールでは使用できません。プラットフォームイベントトリガーログを収集するには、[設定] で追跡フラグエントリを自動化プロセスエンティティに追加します。

[設定] から、[クイック検索] ボックスに「デバッグログ」と入力し、[デバッグログ] をクリックします。
[New (新規)] をクリックします。
[追跡対象エンティティ種別] で、[自動化プロセス] を選択します。
収集するログの開始時刻と有効期限を選択します。
[デバッグレベル] に「*」と入力し、[検索] をクリックします。
事前定義されたデバッグレベル (SFDC_DevConsole など) を選択するか、[New (新規)] をクリックして独自のデバッグレベルを作成します。
[Save (保存)] をクリックします。

Apex テストのデバッグログは例外です。同じテスト実行ログにイベントトリガーのログが含まれます。

プラットフォームイベントトリガーに関する留意点

イベント処理の順序

トリガーは、プラットフォームイベント通知を受信した順序で順次処理します。イベントの順序は、イベントの再実行 ID に基づきます。Apex トリガーはイベントのバッチを一度に受信できます。イベントの順序は、各バッチ内に保持されます。バッチ内のイベントの発信元は、1 つ以上の公開者である可能性があります。

非同期のトリガー実行

プラットフォームイベントトリガーは、独自のプロセス内で非同期に実行され、イベントを公開したトランザクションには含まれません。そのため、イベントが公開されてからトリガーがイベントを処理するまでの間に遅延が発生することがあります。トリガーの実行結果がイベント公開の直後に使用可能になると想定しないでください。

自動化プロセスシステムユーザー

プラットフォームイベントトリガーは、トリガーを実行するユーザー (実行ユーザー) の下では実行されず、自動化プロセスシステムユーザーの下で実行されるため、CloudNewsTrigger の例では、所有者 ID 項目が明示的に設定されています。このトリガーの例では、Regional Dispatch というサンプルユーザーキューの ID が使用されています。ケースや商談など、OwnerId 項目がトリガーにある Salesforce レコードを作成する場合、明示的に所有者 ID を設定してください。ケースとリードの場合、代わりに割り当てルールを使用して所有者を設定できます。

また、イベントトリガーで作成または更新されたレコードのシステム項目 (CreatedById や LastModifiedById など) は、自動化プロセスエンティティを参照します。同様に、Apex の UserInfo.getUserId() ステートメントは自動化プロセスエンティティを返します。

プラットフォームイベントトリガーの実行ユーザーを上書きし、トリガーが自動化プロセスではなくそのユーザーの下で実行されるようにできます。トリガーを設定するには、メタデータ API または Tooling API の PlatformEventSubscriberConfig を使用します。詳細は、『プラットフォームイベント開発者ガイド』の「プラットフォームイベントトリガーのユーザーとバッチサイズの設定」を参照してください。

Apex ガバナ制限

標準またはカスタムオブジェクトトリガーと同様、プラットフォームイベントトリガーには、Apex ガバナ制限が適用されます。

Apex トリガーの制限

プラットフォームイベントトリガーは、カスタムおよび標準オブジェクトトリガーと同じ制限の多くを共有します。たとえば、トリガーから Apex コールアウトを同期して実行することはできません。

トリガーバッチサイズ

プラットフォームイベントトリガーのバッチサイズはイベントメッセージ 2,000 件で、Salesforce オブジェクトトリガーのバッチサイズの 200 より大きくなっています。バッチサイズは Trigger.New リストのサイズに対応します。プラットフォームイベントトリガーのバッチサイズは変更できます。詳細は、『プラットフォームイベント開発者ガイド』の「プラットフォームイベントトリガーのユーザーとバッチサイズの設定」を参照してください。

[設定] のプラットフォームイベント定義詳細ページでは、すべてのイベントトリガーの状態を表示できます。[登録] の下で、有効なトリガーのそれぞれが、実行情報および状態と一緒にリストされます。情報には、最終公開イベントや最終処理イベントの再実行 ID が含まれます。状態は、トリガーが実行中であるか、復旧できないエラーや不十分な権限により登録から切断されているかを示します。トリガーの最大試行回数に達した場合にのみ、エラー状態になります。次のスクリーンショットは、Cloud News イベント詳細ページの [登録] 関連リストを示します。

[登録] 関連リストには、イベントに登録しているフローとプロセスも表示されます。
[登録] 関連リストには、Pub/Sub API、empApi Lightning コンポーネントを使用する登録者は含まれません。他の種別の登録者については、この単元で後ほど説明します。
大規模プラットフォームイベントの場合、[最終公開 ID] の値は使用できず、常に「利用できません」と表示されます。

イベントの Apex トリガーの登録者の管理

システム管理者は、一時停止した登録を停止した場所 (イベントバスで使用可能な最も古いイベントメッセージ) から再開できます。エラーの原因となったイベントメッセージや、不要となったメッセージをバイパスしたい場合は、登録を最新のイベントメッセージから再開できます。

トリガー登録を管理するには、[登録] 関連リストで、Apex トリガーの横にある [管理] をクリックします。

登録詳細ページで、適切なアクションを選択します。

実行中の登録を一時停止するには、[Suspend (サスペンド)] をクリックします。
一時停止した登録をイベントバスで使用可能な最も古いイベントメッセージから再開するには、[再開] をクリックします。
一時停止した登録を最新のイベントメッセージから再開するには、[Resume from Tip (最新から再開)] をクリックします。

フローとプロセスの登録は、[登録] 関連リストでは管理できません。

トリガーを保存すると、トリガー登録が自動的に再開されます。詳細は、『プラットフォームイベント開発者ガイド』の「プラットフォームイベントの詳細ページでのイベントの登録者の表示」を参照してください。

プラットフォームイベントトリガーのテスト

Apex テストを追加して、プラットフォームイベントトリガーが適切に機能することを確認します。Apex コード (トリガーを含む) をパッケージ化または本番環境にリリースする前に、Apex コードをテストする必要があります。Apex テストでプラットフォームイベントを公開するには、publish ステートメントを Test.startTest および Test.stopTest ステートメントで囲みます。

// Create test events
Test.startTest();
// Publish events
Test.stopTest();
// Perform validation here

テストコンテキストで、publish メソッドコールが公開操作をキューに登録します。Test.stopTest() ステートメントにより、イベント公開が実行されます。Test.stopTest() の後に検証を実行します。

次に、Cloud_News イベントのテストクラスと関連付けられたトリガーの例を示します。イベントを公開すると、関連付けられたトリガーが起動します。Test.stopTest() の後、テストでは isSuccess() によって返された Database.SaveResult の値を調べて公開が成功したことを確認します。テストではまた、トリガーが作成したケースを照会します。ケースレコードが見つかった場合、このトリガーは正常に実行され、テストは合格です。

@isTest
public class PlatformEventTest {
    @isTest static void test1() {
        // Create test event instance
        Cloud_News__e newsEvent = new Cloud_News__e(
            Location__c='Mountain City',
            Urgent__c=true,
            News_Content__c='Test message.');
        Test.startTest();
        // Call method to publish events
        Database.SaveResult sr = EventBus.publish(newsEvent);
        Test.stopTest();
        // Perform validation here
        // Verify that the publish was successful
        System.assertEquals(true, sr.isSuccess());
        // Check that the case that the trigger created is present.
        List<Case> cases = [SELECT Id FROM Case];
        // Validate that this case was found.
        // There is only one test case in test context.
        System.assertEquals(1, cases.size());
    }
}

Lightning コンポーネントを使用したプラットフォームイベント通知の登録

Lightning アプリケーションは、empApi Lightning Web または Aura コンポーネントを使用して、アプリケーションのイベントに登録できます。

Lightning Web コンポーネントの empApi メソッドを使用するには、次に示すように lightning/empApi モジュールからこのメソッドをインポートします。

import { subscribe, unsubscribe, onError, setDebugFlag, isEmpEnabled }
    from 'lightning/empApi';

次に、インポートしたメソッドを JavaScript コードでコールします。

lightning/empApi モジュールの使用例と詳細なリファレンスについては、Lightning コンポーネントライブラリの lightning-emp-api に関するドキュメントを参照してください。

Aura コンポーネントで empApi メソッドを使用するには、カスタムコンポーネント内に lightning:empApi コンポーネントを追加して、aura:id 属性を割り当てます。

<lightning:empApi aura:id="empApi"/>

次に、クライアント側コントローラーで、コンポーネントメソッドをコールする関数を追加します。

lightning:empApi コンポーネントの使用例と詳細なリファレンスについては、Lightning コンポーネントライブラリの lightning:empApi に関するドキュメントを参照してください。

クリックを使用したプラットフォームイベント通知の登録

プラットフォームイベントメッセージを受信したときにフローをトリガーするには、プラットフォームイベントトリガーフローを作成します。開始要素で、フローの実行をトリガーするイベントメッセージを使用するプラットフォームイベントを選択します。

フローを作成するときには、$Record グローバル変数を参照することでプラットフォームイベントメッセージの項目値を使用できます。

または、一時停止要素を使用して、フローでプラットフォームイベントに登録できます。その場合、プラットフォームイベントメッセージの受信時にフローを開始する代わりに、そのイベントメッセージによって一時停止中のフローインタビューを再開します。たとえば、Salesforce が Cloud News イベントメッセージを受信するまで一時停止する一時停止要素を次に示します。イベントの場所が {!contact.MailingCity} と一致する場合にのみ再開されます。{!contact} レコード変数には、取引先責任者レコードの値が保存されます。

Flow Builder の一時停止設定

Pub/Sub API では 1 つのインターフェースでプラットフォームイベントの公開とプラットフォームイベントへの登録を実行できます。Pub/Sub API は gRPC API と HTTP/2 に基づいてバイナリイベントメッセージを Apache Avro 形式で効率的に公開、配信します。gRPC はオープンソースのリモートプロシージャーコール (RPC) フレームワークで、gRPC を使用することでデバイス、モバイルアプリケーション、ブラウザーをバックエンドサービスに接続できます。詳細は、gRPC のドキュメントを参照してください。Apache Avro はデータ逐次化システムです。詳細は Apache Avro を参照してください。

Pub/Sub API はプルサブスクリプションモデルを使用しており、クライアントが処理容量に基づいてサーバーからいくつかのイベントを要求します。プッシュベースのサブスクリプションではクライアントがサーバーからプッシュされた新しいイベントの受信を待ちますが、プルサブスクリプションではクライアントが積極的にサーバーからのイベントを要求します。このイベントフローコントロールでは、イベントの公開が急増した場合にクライアントが処理できないほどのイベントを受信することがありません。

Pub/Sub API には次のような利点があります。

1 つの API でイベントの公開、登録、イベントスキーマの取得を実行できる。
公開操作によって、中間のキューへの追加の結果ではなく、最終的な公開の結果が得られる。
フローコントロールで、クライアントのイベント処理速度に基づいて subscribe コールでいくつのイベントを受信するかを指定できる。
HTTP/2 による圧縮を使用したリアルタイムで高パフォーマンスなデータストリーミングを実現できる。
クライアントでは gRPC API で提供される 11 種類のプログラミング言語 (Python、Java、Node、C++ など) がサポートされる。サポートされるすべての言語については https://grpc.io/docs/languages/ を参照してください。

Pub/Sub API クライアントは受信したイベントからスキーマ、再実行 ID、ペイロードを別々に取得し、ペイロードをデコードできます。たとえば、受信した Cloud News イベントのペイロードは次のメッセージのようになります。

{
  "CreatedDate": 1652978695951,
  "CreatedById": "005SM000000146PYAQ",
  "Location__c": "San Francisco",
  "Urgent__c": true,
  "Ink_Percentage__c": "Large highway is closed due to asteroid collision."
}

詳細は Pub/Sub API のドキュメントを参照してください。

Salesforce Platform と外部アプリケーションでのプラットフォームイベントの使用方法を確認しました。可能性は無限です! プラットフォームイベントは、ビジネストランザクションの処理や予防的なカスタマーサービスの取り組みなど、さまざまなアプリケーションやインテグレーションで使用できます。プラットフォームイベントでは、イベントベースのプログラミングモデルを採用して、イベントベースのソフトウェアアーキテクチャの利点を実現できます。

リソース

予想時間

トピック

ヘルプをお探しですか?

Salesforce Platform のリソース

プラットフォームイベントの登録

学習の目的

メモ

デバッグログの設定

プラットフォームイベントトリガーに関する留意点

イベントの Apex トリガーの登録者の管理

プラットフォームイベントトリガーのテスト

予想時間

トピック

ヘルプをお探しですか?

Salesforce Platform のリソース

プラットフォームイベントの登録

学習の目的

メモ