Apex スケジューラを使用したジョブのスケジュール

• スケジュール済み Apex を使用するケース。
• スケジュール済みジョブを監視する方法。
• スケジュール済み Apex の構文。
• scheduled メソッドのベストプラクティス。

global class SomeClass implements Schedulable {
    global void execute(SchedulableContext ctx) {
        // awesome code here
    }
}

サンプルコード

このクラスは、進行中の商談のうち現在の日付までにクローズされているはずのものを照会し、所有者に商談を更新するよう通知する ToDo を各商談に作成します。

global class RemindOpptyOwners implements Schedulable {
    global void execute(SchedulableContext ctx) {
        List<Opportunity> opptys = [SELECT Id, Name, OwnerId, CloseDate
            FROM Opportunity
            WHERE IsClosed = False AND
            CloseDate < TODAY];
        // Create a task for each opportunity in the list
        TaskUtils.remindOwners(opptys);
    }
}

実行するクラスはプログラムを使用して、または Apex スケジューラ UI からスケジュールできます。

RemindOpptyOwners reminder = new RemindOpptyOwners();
// Seconds Minutes Hours Day_of_month Month Day_of_week optional_year
String sch = '20 30 8 10 2 ?';
String jobID = System.schedule('Remind Opp Owners', sch, reminder);

1. [設定] から、[クイック検索] ボックスに「Apex」と入力し、[Apex クラス] を選択します。
2. [Apex をスケジュール] をクリックします。
3. ジョブ名に「Daily Oppty Reminder」などと入力します。
4. Apex クラスの横にあるルックアップボタンをクリックし、検索語に「*」と入力して、スケジュール可能なすべてのクラスのリストを取得します。検索結果で、スケジュール済みクラスの名前をクリックします。
5. [毎週] または [毎月] の頻度を選択して、必要な頻度を設定します。
6. 開始日と終了日、適切な開始時刻を選択します。
7. [保存] をクリックします。

@isTest
private class RemindOppyOwnersTest {
    // Dummy CRON expression: midnight on March 15.
    // Because this is a test, job executes
    // immediately after Test.stopTest().
    public static String CRON_EXP = '0 0 0 15 3 ? 2022';
    static testmethod void testScheduledJob() {
        // Create some out of date Opportunity records
        List<Opportunity> opptys = new List<Opportunity>();
        Date closeDate = Date.today().addDays(-7);
        for (Integer i=0; i<10; i++) {
            Opportunity o = new Opportunity(
                Name = 'Opportunity ' + i,
                CloseDate = closeDate,
                StageName = 'Prospecting'
            );
            opptys.add(o);
        }
        insert opptys;
        // Get the IDs of the opportunities we just inserted
        Map<Id, Opportunity> opptyMap = new Map<Id, Opportunity>(opptys);
        List<Id> opptyIds = new List<Id>(opptyMap.keySet());
        Test.startTest();
        // Schedule the test job
        String jobId = System.schedule('ScheduledApexTest',
            CRON_EXP,
            new RemindOpptyOwners());
        // Verify the scheduled job has not run yet.
        List<Task> lt = [SELECT Id
            FROM Task
            WHERE WhatId IN :opptyIds];
        System.assertEquals(0, lt.size(), 'Tasks exist before job has run');
        // Stopping the test will run the job synchronously
        Test.stopTest();
        // Now that the scheduled job has executed,
        // check that our tasks were created
        lt = [SELECT Id
            FROM Task
            WHERE WhatId IN :opptyIds];
        System.assertEquals(opptyIds.size(),
            lt.size(),
            'Tasks were not created');
    }
}

• スケジュール済み Apex ジョブは一度に 100 件しか設定できず、スケジュール済み Apex の 24 時間あたりの最大実行数も制限されています。詳細は、「リソース」セクションの「実行ガバナと制限」を参照してください。
• クラスをトリガからスケジュールする場合は、細心の注意を払ってください。制限を超えるスケジュール済みジョブをトリガで追加しないようにする必要があります。
• 同期 Web サービスコールアウトは、スケジュールされた Apex からは実行できません。コールアウトを実行するには、@future(callout=true) のアノテーションを付加したメソッドにコールアウトを配置し、このメソッドをスケジュールされた Apex からコールすることで非同期コールアウトを実行します。ただし、スケジュールされた Apex で一括処理ジョブを実行する場合、一括処理クラスからコールアウトを実行できます。

• Apex スケジューラ
• 実行ガバナと制限