Crear reglas de validación

Objetivos de aprendizaje

Después de completar esta unidad, podrá:

• Describir dos casos de uso para reglas de validación.
  
• Indicar los elementos de una regla de validación.
  
• Crear una regla de validación.
  

Nota

¿Es su idioma de aprendizaje español (LATAM)? Comience el reto en un Trailhead Playground en español (LATAM) y copie y pegue los valores en español (LATAM). Si no aprueba el reto en su organización en español (LATAM), recomendamos que (1) cambie la configuración local a Estados Unidos, (2) cambie el idioma a inglés (según estas instrucciones) y, luego, (3) haga clic en el botón “Check Challenge” (Comprobar el reto) nuevamente.

Consulte la insignia Trailhead en su idioma para obtener más información sobre cómo aprovechar la experiencia de Trailhead en otros idiomas.

Introducción a las reglas de validación

Las reglas de validación verifican que los datos ingresados por usuarios en registros cumplen los estándares que especifica antes de poder guardarlos. Una regla de validación puede contener una fórmula o expresión que evalúa los datos en uno o más campos y ofrece un valor “Verdadero” o “Falso”. Cuando la regla de validación devuelve un valor "Verdadero", esto confirma que los datos ingresados por el usuario contienen un valor no válido. Las reglas de validación también pueden incluir mensajes de error para mostrar a los usuarios cuando ingresan valores no válidos basándose en criterios específicos. El uso de estas reglas contribuye de forma efectiva en aumentar la calidad de los datos. Por ejemplo, puede asegurarse de que todos los campos de número de teléfono contienen un formato específico o que los descuentos aplicados a algunos productos nunca superen un porcentaje definido.

Definición de reglas de validación

Puede crear reglas de validación para objetos, campos, miembros de campaña o eventos clave de casos. En estos pasos, crearemos una regla de validación que se active cuando un usuario intente guardar una cuenta con un número de cuenta de longitud incorrecta.

Creación de una regla de validación

1. En Setup (Configuración), vaya a Object Manager (Gestor de objetos) y haga clic en Account (Cuenta).
   
2. En la barra lateral izquierda, haga clic en Validation Rules (Reglas de validación).
   
3. Haga clic en New (Nuevo).
   
4. Ingrese las siguientes propiedades para su regla de validación:
   
   1. Nombre de regla: Account_Number_8_Characters
   2. Fórmula de condición de error: LEN( AccountNumber) <> 8
5. Mensaje de error: El número de cuenta debe tener 8 caracteres de longitud.
6. Haga clic en Check Syntax (Comprobar sintaxis) para comprobar si la fórmula tiene errores.
   
7. Para terminar, haga clic en Save (Guardar).
   

Aquí le explicamos cómo aparece el mensaje de error de una regla de validación cuando un usuario escribe un formato de número de cuenta incorrecto en un campo.

Ejemplos de reglas de validación

Existen algunos ejemplos de regla de validación que puede probar por si mismo.

Número de cuenta es numérico

La función AND devuelve un valor "Verdadero" si todos los valores de la fórmula son verdaderos, y un valor "Falso" si uno o más valores son falsos. La función ISBLANK determina si una expresión tiene un valor. La función ISNUMBER determina si un valor de expresión es un número. La función NOT devuelve FALSO para VERDADERO y VERDADERO para FALSO. En el ejemplo, la regla de validación determina si un número de cuenta es tanto no en blanco y no un número. Un valor "Verdadero" indica que los datos ingresados por el usuario contienen un valor no válido. O sea, si el usuario introduce un valor no numérico para un número de cuenta, la regla de validación devuelve una respuesta "Verdadero" y envía un mensaje de error.  

AND(
   NOT(ISBLANK(AccountNumber)),
   NOT(ISNUMBER(AccountNumber))
)

La fecha debe ser del año actual

La función YEAR devuelve el año con cuatro dígitos de una fecha específica. La función TODAY devuelve la fecha actual. El operador <> (No es igual a) determina si un valor no es igual a otro. En el ejemplo, la regla de validación determina si el año de una fecha específica no es igual a la fecha de año de hoy. Un valor "Verdadero" indica que los datos ingresados por el usuario contienen un valor no válido. O sea, si el usuario introduce una fecha que no está en el año actual, la regla de validación devuelve una respuesta "Verdadero" y envía un mensaje de error.

Validación de intervalo de números

En el ejemplo, la regla de validación determina si la diferencia entre dos valores (Salario máximo y Salario mínimo) es superior a 20.000 USD. Un valor "Verdadero" indica que los datos ingresados por el usuario contienen un valor no válido. O sea, si el usuario introduce dos valores cuya diferencia supera el intervalo de salario de 20.000 USD, la regla de validación devuelve una respuesta "Verdadero" y envía un mensaje de error.

Extensión del sitio Web

La función AND devuelve un valor "Verdadero" si todos los valores de la fórmula son verdaderos, y un valor "Falso" si uno o más valores son falsos. El operador <> (No es igual a) determina si un valor no es igual a otro. En el ejemplo, si el usuario ingresa una URL de sitio web con una extensión que no es igual a las seis extensiones válidas, la regla de validación muestra una respuesta "True" (Verdadero) y envía un mensaje de error. Si el usuario ingresa una URL de sitio web con una extensión que es idéntica a una de las seis extensiones válidas, la regla de validación muestra una respuesta "False" (Falso) y no envía un mensaje de error, ya que los datos que ingresó el usuario son válidos.

AND(
   RIGHT( Web_Site__c, 4) <> ".COM",
   RIGHT( Web_Site__c, 4) <> ".com",
   RIGHT( Web_Site__c, 4) <> ".ORG",
   RIGHT( Web_Site__c, 4) <> ".org",
   RIGHT( Web_Site__c, 4) <> ".NET",
   RIGHT( Web_Site__c, 4) <> ".net"
 )

País de facturación válido

La función OR devuelve una respuesta "Verdadero" si una o más expresiones de la fórmula son verdaderas, y devuelve una respuesta "Falso" si todas las expresiones son falsas. La función LEN devuelve el número de caracteres de una cadena de texto especificada. En el ejemplo, la regla de validación determina si el valor que el usuario ingresó para el código de País de facturación es de un carácter (en vez de los dos obligatorios) o no contiene uno de los códigos de dos caracteres válidos. Si cualquiera de estas condiciones es verdadera, la regla de validación devuelve un valor de "Verdadero" y envía un mensaje de error. Si el usuario ingresa un código de País de facturación válido, ambas expresiones de la fórmula son falsas: LEN no es 1 y los datos contienen uno de los valores válidos. En este caso, la regla de validación devuelve un valor "Falso" y no envía un mensaje de error.

OR(
LEN(BillingCountry) = 1,
NOT(
CONTAINS(
"AF:AX:AL:DZ:AS:AD:AO:AI:AQ:AG:AR:AM:" &
"AW:AU:AZ:BS:BH:BD:BB:BY:BE:BZ:BJ:BM:BT:BO:" &
"BA:BW:BV:BR:IO:BN:BG:BF:BI:KH:CM:CA:CV:KY:" &
"CF:TD:CL:CN:CX:CC:CO:KM:CG:CD:CK:CR:CI:HR:" &
"CU:CY:CZ:DK:DJ:DM:DO:EC:EG:SV:GQ:ER:EE:ET:FK:" &
"FO:FJ:FI:FR:GF:PF:TF:GA:GM:GE:DE:GH:GI:GR:GL:" &
"GD:GP:GU:GT:GG:GN:GW:GY:HT:HM:VA:HN:HK:HU:" &
"IS:IN:ID:IR:IQ:IE:IM:IL:IT:JM:JP:JE:JO:KZ:KE:KI:" &
"KP:KR:KW:KG:LA:LV:LB:LS:LR:LY:LI:LT:LU:MO:MK:" &
"MG:MW:MY:MV:ML:MT:MH:MQ:MR:MU:YT:MX:FM:MD:MC:" &
"MC:MN:ME:MS:MA:MZ:MM:MA:NR:NP:NL:AN:NC:NZ:NI:" &
"NE:NG:NU:NF:MP:NO:OM:PK:PW:PS:PA:PG:PY:PE:PH:" &
"PN:PL:PT:PR:QA:RE:RO:RU:RW:SH:KN:LC:PM:VC:WS:" &
"SM:ST:SA:SN:RS:SC:SL:SG:SK:SI:SB:SO:ZA:GS:ES:" &
"LK:SD:SR:SJ:SZ:SE:CH:SY:TW:TJ:TZ:TH:TL:TG:TK:" &
"TO:TT:TN:TR:TM:TC:TV:UG:UA:AE:GB:US:UM:UY:UZ:" &
"VU:VE:VN:VG:VI:WF:EH:YE:ZM:ZW",
BillingCountry)))

Recursos

• Ayuda de Salesforce: Reglas de validación
  
• Ayuda de Salesforce: Gestión de reglas de validación
  
• Ayuda de Salesforce: Sugerencias de escritura de reglas de validación
  
• Ayuda de Salesforce: Operaciones y funciones de fórmulas por contexto