Erfassen Sie Ihre Fortschritte
Trailhead-Startseite
Trailhead-Startseite

Verwenden von Textformeln

Lernziele

Nachdem Sie diese Lektion abgeschlossen haben, sind Sie in der Lage, die folgenden Aufgaben auszuführen:
  • Beschreiben des Typs "Text"
  • Konvertieren von Textwerten in andere Datentypen und umgekehrt
  • Beschreiben von Anwendungsfällen für Formeln des Typs "Text"
  • Erstellen einer Formel mithilfe des Typs "Text"

Einführung in Text in Formeln

Mitunter ist es am einfachsten, Informationen in Ihrem Unternehmen auf einen Blick lesbar zu machen, indem Sie sie als Text anzeigen. Formeln mit dem Rückgabetyp "Text" können Textwerte verketten, Zahlen und Datumsangaben in Text umwandeln oder Text bedingt anzeigen.

Das Einfachste, was Sie tun können, ist das Verketten zweier Textzeichenfolgen mit dem Operator &. So können Sie beispielsweise den vollständigen Namen eines Kontakts anzeigen, indem Sie den Vor- und Nachnamen kombinieren.

FirstName & " " & LastName

Berücksichtigen Sie bei der Kombination von Textwerten die notwendigen Leerzeichen, damit Ihre Zeichenketten nicht unsinnig erscheinen. "Anna Schmitz" ist viel besser lesbar als "AnnaSchmitz".

Gängige Textfunktionen und -operatoren

Salesforce bietet zahlreiche Funktionen und Operatoren, die Ihnen die Arbeit mit Text in Formeln erleichtern. Mithilfe von Formeln können Sie andere Datentypen in Text konvertieren und Textwerte verketten oder in einem Textfeld nach einer bestimmten Zeichenfolge suchen.

Konvertieren in Textwerte und umgekehrt

Mit TEXT() lässt sich ein Feld des Typs "Prozent", "Zahl", "Datum", "Datum/Uhrzeit", "Auswahlliste" oder "Währung" in Text umwandeln. TEXT() gibt die Ausgabe ohne Formatierung, Kommas oder Währungszeichen zurück. Beispiel TEXT(percent_value): Wenn percent_value auf 30 % festgelegt ist, wird 0,3 zurückgegeben.

Wenn TEXT() einen Datums- oder Datum/Uhrzeit-Wert empfängt, wird eine Zeichenfolge mit der Standardformatierung für Datum oder Datum/Uhrzeit zurückgegeben. Beispiel: Wenn date_value dem 17. März 2015 entspricht, gibt TEXT(date_value) den Wert 2015-03-17 zurück. Wenn datetime_value 17. März 2015, 17:00 Uhr ist, gibt TEXT(datetime_value) den Wert 2015-03-17 17:00:00Z zurück. Das Z bedeutet, dass die Zeit in GMT zurückgegeben wird. TEXT() gibt Datum/Uhrzeit-Werte in GMT und nicht in der Zeitzone des aktuellen Benutzers oder Ihres Unternehmens zurück.

Sie können Werte mit der VALUE()-Funktion auch umgekehrt konvertieren, die einen Textwert verwendet und eine Zahl zurückgibt. Wenn VALUE() einen Wert empfängt, der keine Zahl ist, einschließlich anderer Sonderzeichen als Dezimalpunkt oder Minuszeichen, wird #Fehler! angezeigt. Wenn text_value beispielsweise "$500" ist, gibt VALUE(text_value) einen Fehler zurück. VALUE() gibt auch einen Fehler zurück, wenn text_value leer ist.

Andere Textfunktionen

BEGINS(text, compare_text) gibt TRUE zurück, wenn der Text mit compare_text beginnt. CONTAINS(text, compare_text) gibt TRUE zurück, wenn compare_text sich irgendwo in text befindet. Diese Funktionen sind nützlich, um Informationen basierend auf einem Textfeld bedingt anzuzeigen.

Die Funktion SUBSTITUTE(text, old_text, new_text) gibt Text mit einer beliebigen Instanz von old_text zurück, die durch new_text ersetzt wurde, ähnlich der Funktion zum Suchen und Ersetzen in einem Texteditor.

Salesforce bietet weitere Funktionen zum Arbeiten mit und Formatieren von Text in Formeln. Weitere Informationen finden Sie in der Salesforce-Onlinehilfe unter Formeloperatoren und -funktionen.

Verwenden des Typs "Text" in Formeln

Zuweisen einer Account-Bewertung

Häufig zeigen Formeln mit dem Rückgabetyp "Text" Informationen an, die sich kaum quantifizieren lassen. Sie können beispielsweise eine Textformel verwenden, um festzustellen, ob ein Lead heiß, warm oder kalt ist. Wir schreiben eine Formel, die sowohl bedingte Logik als auch die ISPICKVAL()-Funktion verwendet, um eine Lead-Bewertung zurückzugeben.

Bei diesem Beispiel bewerten wir einen Lead anhand von Umsatz, Land und Quelle.

  • Heiß: AnnualRevenue (Jahresumsatz) mehr als 1 Mio. US-Dollar, Country (Land) USA und LeadSource (Lead-Quelle) "Partnerempfehlung".
  • Warm: AnnualRevenue (Jahresumsatz) mehr als 1 Mio. US-Dollar, Country (Land) USA und LeadSource (Lead-Quelle) entweder "Gekaufte Liste" oder "Web".
  • Kalt: Der Account erfüllt keine dieser Bedingungen.

Diese Formel verwendet eine Reihe von IF()-, AND()- und OR()-Anweisungen, um diese Bedingungen zu überprüfen, und wertet das Feld Lead-Quelle mithilfe von ISPICKVAL() aus. Die Formel verwendet auch eine CASE()-Anweisung, um das Land zu überprüfen. Wenn das Land "US", "USA", "America" oder "United States" ist, gibt die CASE()-Anweisung US zurück. Andernfalls wird NA (nicht zutreffend) zurückgegeben.

Ein Entscheidungsbaum hilft uns, dem logischen Ablauf unserer Formel leichter zu folgen.

Dieser Entscheidungsbaum hilft bei der Visualisierung der Formel zur Lead-Bewertung.
  1. Nutzen Sie in Setup das Feld "Schnellsuche", um zum Objekt-Manager zu wechseln.
  2. Klicken Sie auf Lead | Felder & Beziehungen und dann auf Neu.
  3. Wählen Sie Formel aus und klicken Sie auf Weiter.
  4. Geben Sie Bewertung in Feldbezeichnung ein. "Feldname" wird automatisch ausgefüllt.
  5. Wählen Sie Text aus und klicken Sie auf Weiter.
  6. Geben Sie die folgende Formel ein:
    IF(
      AnnualRevenue > 1000000 &&
      CONTAINS(CASE(Country, "United States", "US", "America", "US",
        "USA", "US", "US", "US", "NA"), "US"),
      IF(
        ISPICKVAL(LeadSource, "Partner Referral"), "Hot",
        IF(
          ISPICKVAL(LeadSource, "PurchasedList") ||
          ISPICKVAL(LeadSource, "Web"),
          "Warm", "Cold"
        )
      ), "Cold"
    )

Das neue Formelfeld Bewertung zeigt "Heiß", "Warm" oder "Kalt" basierend auf den Eigenschaften eines Lead an.

Anzeigen eines Bilds mithilfe von CASE()

Formeln mit dem Rückgabetyp "Text" sind für mehr als nur Text nützlich, denn Sie können sie auch zur Anzeige von Bildern verwenden. Bilder machen es einfach, Informationen auf einen Blick zu erfassen, und fallen dem Benutzer mehr ins Auge als Text allein. Schreiben wir eine Formel, die das soeben erstellte Feld Bewertung verwendet, um die Bewertung eines Leads grafisch mit null, eins, drei oder fünf von fünf Sternen anzuzeigen.

Die IMAGE()-Funktion unterstützt bis zu vier Argumente. IMAGE(image_url, alternate_text, height, width) zeigt das von image_url angegebene Bild mit den von den optionalen Argumenten "height" und "width" angegebenen Abmessungen an. Wenn das Bild nicht angezeigt werden kann, zeigt die Funktion alternate_text (alternativer Text) an.

Wenn die Bewertung des Leads

  • "Heiß" ist, zeigt die Formel fünf Sterne
  • "Warm" ist, zeigt die Formel drei Sterne
  • "Kalt" ist, zeigt die Formel einen Stern

Wenn die Bewertung des Leads leer ist, zeigt die Formel keine Sterne.

Erstellen Sie ein Formelfeld mit dem Rückgabetyp "Text" und dem Namen Sternebewertung. Geben Sie im Editor für erweiterte Formeln Folgendes ein:

IMAGE(
  CASE(Rating__C,
    "Hot", "/img/samples/stars_500.gif",
    "Warm", "/img/samples/stars_300.gif",
    "Cold", "/img/samples/stars_100.gif",
    "/img/samples/stars_000.gif"),
"Unknown")

Diese Formel verwendet Bilder, die in Salesforce integriert sind, aber Sie können Ihre eigenen Bilder verwenden, indem Sie sie zuerst von der Registerkarte "Dokumente" hochladen.

Textbeispiele

  1. Dieses Formular nutzt das Feld "Billing State/Province" eines in den USA ansässigen Accounts, um ihn als "North", "South", "East", "West" oder "Central" zu klassifizieren.
    IF(ISBLANK(BillingState), "None",
    IF(CONTAINS("AK:AZ:CA:HA:NV:NM:OR:UT:WA", BillingState), "West",
    IF(CONTAINS("CO:ID:MT:KS:OK:TX:WY", BillingState), "Central",
    IF(CONTAINS("CT:ME:MA:NH:NY:PA:RI:VT", BillingState), "East",
    IF(CONTAINS("AL:AR:DC:DE:FL:GA:KY:LA:MD:MS:NC:NJ:SC:TN:VA:WV", BillingState), "South",
    IF(CONTAINS("IL:IN:IA:MI:MN:MO:NE:ND:OH:SD:WI", BillingState), "North", "Other"))))))
  2. Diese Formel bettet mithilfe der HYPERLINK()-Funktion einen Link ein. Im Allgemeinen zeigt HYPERLINK(url, display_text, target) einen Link zur URL mit display_text (Anzeigetext) an. Das optionale Argument "target" (Ziel) bestimmt, wie die Webseite angezeigt wird, wenn auf den Link geklickt wird. Wenn Sie "target" leer lassen, wird der Link standardmäßig in einem neuen Browserfenster geöffnet.
    HYPERLINK("https://www.salesforce.com", "Salesforce")
  3. Diese Formel verwendet das Feld "Email" und nutzt es zum Erstellen eines URL. Die Formel verwendet FIND() und SUBSTITUTE(), um das @-Zeichen in der E-Mail-Adresse zu bestimmen und alles links davon durch www zu ersetzen.
    SUBSTITUTE(Email, LEFT(Email, FIND("@", Email)), "www.")

Gängige Fehler bei Textformeln

Konvertieren von Werten in Text. Überprüfen Sie unbedingt den Typ eines Felds, bevor Sie es in einer Formel verwenden. Ein früherer Salesforce-Administrator hat möglicherweise ein benutzerdefiniertes Feld erstellt, das ein Datum als Textwert enthält. In diesem Fall können Sie TEXT() oder DATEVALUE() verwenden, um mit Text- und Datumswerten gleichzeitig zu arbeiten.

Hilfsformelfelder

Hilfsformelfelder eignen sich besonders dafür, Ihre Formeln kurz und leicht verständlich zu halten. Ein Hilfsformelfeld ist nur ein Teil einer größeren Berechnung und wird vom Endformelfeld referenziert. Sie können Hilfsformelfelder mit jeder Art von Formel verwenden. Nachstehend finden Sie ein Beispiel.

Angenommen, Sie möchten eine Textformel namens Case_Category__c schreiben, die eine Kategorie für einen Kundenvorgang (Grün, Gelb oder Rot) anzeigt, je nachdem, wie lange dieser Kundenvorgang bereits offen ist. Normalerweise würden Sie etwas wie das hier schreiben.

IF(((NOT(IsClosed)) && (TODAY() - DATEVALUE(CreatedDate) > 20)), "RED",
 IF((NOT(IsClosed)) && (TODAY() - DATEVALUE(CreatedDate) > 10), "YELLOW",
 "GREEN"))
Sie können diese Formel vereinfachen, indem Sie die Logik zur Berechnung des Alters des Kundenvorgangs in ein anderes Formelfeld stellen. Lassen Sie uns dieses Feld Case_Age_In_Days__c nennen.
TODAY() - DATEVALUE(CreatedDate)
Anschließend können wir Case_Category__c so umschreiben.
IF(((NOT(IsClosed)) && (Case_Age_In_Days__c > 20)), "RED",
 IF((NOT(IsClosed)) && (Case_Age_In_Days__c > 10), "YELLOW",
 "GREEN"))
Diese Formel ist nicht nur kürzer und leichter zu verstehen, sondern Sie können Ihre Hilfsformel auch überall dort wiederverwenden, wo Sie das Alter eines Kundenvorgangs berechnen müssen. Super!