Erfassen Sie Ihre Fortschritte
Trailhead-Startseite
Trailhead-Startseite

Verwenden von Zahlen, Währungen und Prozentsätzen in Formeln

Lernziele

Nachdem Sie diese Lektion abgeschlossen haben, sind Sie in der Lage, die folgenden Aufgaben auszuführen:
  • Beschreiben der Rückgabetypen von Formeln des Typs "Zahl", "Währung" und "Prozent"
  • Erläutern des Unterschieds zwischen den Typen "Zahl", "Währung" und "Prozent"
  • Beschreiben von Anwendungsfällen für Formeln der Typen "Zahl", "Währung" und "Prozent"
  • Erstellen einer Formel mithilfe der Typen "Zahl", "Währung" und "Prozent"

Einführung in die Typen "Zahl", "Währung" und "Prozent" in Formeln

Wenn die meisten Menschen das Wort Formel hören, stellen sie sich etwas mit Zahlen vor. Bei Formeln in Salesforce ist das zwar nicht immer der Fall, aber einige Datentypen basieren auf Zahlen. Der einfachste dieser Datentypen ist der Typ "Zahl". Wenn Sie ein Formelfeld erstellen, das eine Zahl zurückgibt, können Sie angeben, wie viele Dezimalstellen von 0 bis 18 Ihre Zahl hat.

Zahlen können positiv oder negativ, ganzzahlig oder dezimal sein. Zahlen eignen sich gut für Messungen wie z. B. von Temperaturen, Längen und Beständen. Währungen haben hingegen einen eigenen Datentyp. Eine Formel, die Währungsdaten zurückgibt, ähnelt einer Zahlenformel mit der Ausnahme, dass Währungswerte mit einem integrierten Währungssymbol versehen sind.

Hinweis

Hinweis

Benutzerdefinierte Formelfelder mit Währungen sind keiner bestimmten Währung zugeordnet. Wenn in Ihrem Unternehmen die Option für mehrere Währungen aktiviert ist, wird das Ergebnis einer Währungsformel in der Währung des zugehörigen Datensatzes angezeigt.

Prozentsätze haben auch einen eigenen Datentyp, nämlich eine Zahl mit einem Prozentzeichen. Ein Prozentsatz wird als Zahl geteilt durch 100 gespeichert, was bedeutet, dass 100 % als 1, 90 % als 0,9 usw. dargestellt wird.

Sie können diese drei numerischen Datentypen in Formeln kombinieren und abgleichen, wobei Sie jedoch deren Unterschiede berücksichtigen sollten. Und denken Sie immer daran, dass der Wert, den Ihre Formel zurückgibt, nicht mehr als 18 Stellen umfassen darf, einschließlich der Ziffern vor und hinter der Dezimalstelle.
Typ der Formelrückgabe Merkmale
Zahl Eine positive oder negative Zahl, entweder eine ganze oder Dezimalzahl.
Währung Eine Zahl mit einem Währungssymbol.
Prozent Eine mit einem Prozentzeichen versehene Zahl, die als durch 100 geteilte Zahl gespeichert wird.

Gängige Funktionen und Operatoren für Zahlen, Währung und Prozent

Bei der Arbeit mit Zahlen verwenden Sie häufig bestimmte Funktionen und Operatoren.

Mathematische Operatoren

Die am häufigsten verwendeten Operatoren in Formeln, die eine Zahl, eine Währung oder einen Prozentsatz zurückgeben, sind die mathematischen Zeichen, die Sie seit Ihrem ersten Rechenunterricht kennen.

Sie können numerische Werte addieren (+), subtrahieren (-), multiplizieren (*) oder dividieren (/). Sie können in Formeln auch die Potenzierung (^) nutzen. Diese Operatoren funktionieren genau wie auf einem Taschenrechner. Formeln richten sich nach der Reihenfolge der Operationen, die Sie in Klammern gruppieren können.

Sie können auch die Zeichen "Größer als" (>), "Kleiner als" (<), "Kleiner oder gleich" (<=) oder "Größer oder gleich" (>=) zum Vergleichen zweier numerischer Werte verwenden. Um zu prüfen, ob zwei Zahlen gleich sind, verwenden Sie =. Um zu prüfen, ob zwei Zahlen ungleich sind, verwenden Sie "Ungleich", was entweder als != oder <> geschrieben werden kann.

Mathematische Funktionen

Der Formel-Editor bietet auch einige andere mathematische Funktionen. Die Funktion ROUND() rundet einen numerischen Wert ab, den Sie ihr angeben. Sie befolgt den Grundsatz, dass ab der Hälfte aufgerundet wird. 1,45 wird beispielsweise zu 1,5 und 1,43 zu 1,4.

Diese Währungsformel verwendet ROUND(), um einen Rabatt zu berechnen und ihn auf zwei Dezimalstellen zu runden, sodass es sich um einen ordnungsgemäßen Währungsbetrag handelt.

ROUND(Price__c - Price__c * Discount__c, 2)

Sie können auch integrierte Operatoren verwenden, um mehrere andere mathematische Funktionen auszuführen, wie Absolutwert, Obergrenze oder Untergrenze. Weitere Informationen zu mathematischen Funktionen finden Sie in der Salesforce-Hilfe unter Formeloperatoren und -funktionen.

Verwenden von Zahlen, Währungen und Prozentsätzen in Formeln

Sie können die Typen "Zahl", "Währung" und "Prozent" in den unterschiedlichsten Situationen in Formeln verwenden – von der Berechnung der prozentualen Provision auf einen Verkauf bis zur Summierung von Jahresumsatz oder -gewinn.

Erstellen eines benutzerdefinierten Felds für "Principal" (Kapital)

  1. Nutzen Sie in Setup das Feld "Schnellsuche", um zum Objekt-Manager zu wechseln.
  2. Klicken Sie auf Account | Felder & Beziehungen und dann auf Neu.
  3. Wählen Sie Währung aus und klicken Sie auf Weiter.
  4. Geben Sie "Principal" (Kapital) in Feldbezeichnung ein. "Feldname" wird automatisch ausgefüllt.
  5. Geben Sie in Dezimalstellen den Wert 2 ein. Da es sich um einen Währungsbetrag handelt, benötigen wir zwei Nachkommastellen.
  6. Ändern Sie Länge in 16. Behalten Sie für die restlichen Optionen die Standardwerte bei und klicken Sie auf Weiter.
  7. Klicken Sie erneut auf Weiter und dann auf Speichern.
Wir verwenden Principal (Kapital), um einen bedingten Zinssatz zu berechnen, mit dessen Hilfe wir dann den Betrag der Zinseszinsen für das Konto berechnen können.

Berechnen des Zinssatzes

Für dieses Konto nehmen wir an, dass, wenn der Kapitalsaldo unter 10.000 US-Dollar liegt, der jährliche Zinssatz 2 % oder 0,02 beträgt. Wenn der Saldo im Bereich von 10.000 bis 100.000 US-Dollar liegt, ist der Zinssatz 3 % oder 0,03. Wenn der Saldo über 100.000 US-Dollar liegt, ist der Zinssatz 4 % oder 0,04.

Bei gegebenem Principal (Kapital) verwenden wir IF(), um den passenden Zinssatz zu bestimmen.

  1. Klicken Sie im Objekt-Manager auf Account | Felder & Beziehungen und auf Neu.
  2. Wählen Sie Formel aus und klicken Sie auf Weiter.
  3. Geben Sie "Interest Rate" (Zinssatz) in Feldbezeichnung ein. "Feldname" wird automatisch ausgefüllt.
  4. Wählen Sie Prozent aus und belassen Sie die Dezimalstellen auf der Standardeinstellung 2.
  5. Klicken Sie auf Weiter.
  6. Geben Sie die folgende Formel ein:
    IF(Principal__c < 10000, 0.02,
      IF(Principal__c >= 10000 &&
        Principal__c < 100000, 0.03, 0.04))
    Hinweis Unsere if-Anweisung hat eine Schwachstelle: Wenngleich Währungsbeträge negativ sein können, gehen wir davon aus, dass Principal__c positiv ist. Falls nicht, ist dieses Konto in Schwierigkeiten!

Jetzt haben wir einen Kapitalbetrag und einen Zinssatz, also alles, was notwendig ist, um die auf einem Konto aufgelaufenen Zinsen zu berechnen.

Berechnen der auf einem Konto aufgelaufenen Zinsen

Wir erstellen eine Formel, die die Zinsen für ein Konto mithilfe von Principal und der Anzahl der Jahre der Laufzeit des Kontos berechnet. Glücklicherweise gibt es bereits eine mathematische Formel zur Berechnung der Zinsen eines Kontos im Zeitverlauf: A = Pe^(rt), die die folgenden Variablen aufweist.

Variable Value (Wert)
P Der Kapitalbetrag auf dem Konto
e Die mathematische Konstante 2,71828182845904
r Der jährliche Zinssatz des Kontos
t Die Laufzeit des Kontos in Jahren

Jetzt können wir die Formel an unsere Felder anpassen.

  1. Klicken Sie im Objekt-Manager auf Account | Felder & Beziehungen und auf Neu.
  2. Wählen Sie Formel aus und klicken Sie auf Weiter.
  3. Geben Sie "Aufgelaufene Zinsen" in Feldbezeichnung ein. "Feldname" wird automatisch ausgefüllt.
  4. Fügen Sie das Feld "Principal" in den Formel-Editor ein. Wir wollen "Principal" mit in die Potenz des Zinssatzes erhobenem "e" multiplizieren, multipliziert mit der Anzahl der Jahre, die das Konto bereits geöffnet ist. Dies können wir mit der EXP()-Funktion realisieren.
  5. Fügen Sie den Operator * (Multiplizieren) ein.
  6. Wählen Sie die Registerkarte "Erweiterte Formel" aus und fügen Sie die Funktion EXP ein. EXP(number) potenziert die Basis "e" mit "number".
  7. Erstellen Sie anstelle von "number" die Formel für den Zinssatz: Fügen Sie zunächst das zuvor erstellte Feld Interest_Rate__c zwischen den Klammern ein.
  8. Wählen Sie die Registerkarte "Einfache Formel" aus und fügen Sie den Operator * (Multiplizieren) hinter dem Feld Interest_Rate__c ein.
  9. Wählen Sie die Registerkarte "Erweiterte Formel" aus und fügen Sie die Funktion YEAR hinter dem Operator * (Multiplizieren) ein.
  10. Fügen Sie in der Funktion YEAR anstelle von date die Funktion TODAY ein.
  11. Wählen Sie die Registerkarte "Einfache Formel" aus. Fügen Sie den Operator - (Subtrahieren) hinter der zweiten geschlossenen Klammer am Ende der Formel ein (die geschlossene Klammer für die Funktion YEAR).
  12. Wählen Sie die Registerkarte "Erweiterte Formel" aus und fügen Sie die Funktion VALUE hinter dem Operator - (Subtrahieren) ein.
  13. Fügen Sie in der Funktion VALUE anstelle von "number" die Funktion YearStarted ein.
Dies liefert uns unsere letzte Funktion.
Principal__c * EXP(Interest_Rate__c * (YEAR(TODAY()) - VALUE(YearStarted)))

Nachdem Sie die Funktion in den Formel-Editor eingegeben haben, können Sie auf Weiter klicken. Klicken Sie auf der Seite "Feldsicherheit" auf Weiter und dann auf Speichern, um Ihre Formel fertigzustellen.

Herzlichen Glückwunsch! Sie haben erfolgreich eine Formel zur Berechnung der auf einem Konto aufgelaufenen Zinseszinsen geschrieben! Sie können sie auf einer beliebigen Kontoseite in Aktion erleben.

Beispiele für Zahlenformeln

  1. Ausgehend vom Margenprozentsatz, der Anzahl verkaufter Artikel und dem Preis pro Artikel berechnet diese Formel den Bruttomargengewinn.
    Margin_percent__c * Items_Sold__c * Price_Item__c
  2. Diese Währungsformel berechnet eine Provision unter Annahme einer maximalen Provision von 500 US-Dollar. Unter Berücksichtigung des Vorhandenseins des benutzerdefinierten Prozentfelds "Commission" (Provision) und des benutzerdefinierten Währungsfelds "Sale" (Umsatz) gibt diese Formel den geringeren Betrag zwischen 500 US-Dollar und dem Prozentsatz der Provision multipliziert mit dem Umsatzbetrag zurück.
    MIN(500, Sale__c * Commission__c)
  3. Zahlenformeln sind hilfreich für die Umrechnung von Grundeinheiten. Diese Formel rechnet Temperaturen von Celsius in Fahrenheit um.
    1.8 * Degrees_Celsius__c + 32
    Und diese rechnet Meilen in Kilometer um.
    Miles__c / 0.6213711921

Gängige Fehler bei Zahlenformeln

  • Dividieren durch Null. Die Regeln, die Sie aus der Mathematik kennen, gelten auch für das Schreiben von Zahlenformeln. Wenn in Ihrer Formel eine Division durch 0 erfolgt, erhalten Sie später eine Fehlermeldung. Wenn Sie zwei Zahlen dividieren, stellen Sie sicher, dass der Nenner nie Null ist. Es ist besonders wichtig, an die Division durch Null zu denken, wenn die Division durch ein anderes Feld erfolgt, dessen Wert sich ändern kann. Wenn Sie trotzdem durch eine Zahl dividieren möchten, die null sein könnte, verwenden Sie eine IF()-Anweisung, um sicherzustellen, dass kein Fehler auftritt. Diese Formel berechnet beispielsweise den Umsatzerlös pro Mitarbeiter eines Accounts, indem "Annual Revenue" (Jahresumsatz) durch "Number of Employees" (Anzahl der Mitarbeiter) dividiert wird. Wenn es keine Mitarbeiter gibt, gibt die Formel 0 zurück, anstatt einen Fehler auszulösen.
    IF(NumberOfEmployees <> 0, AnnualRevenue / NumberOfEmployees, 0)
  • Prüfen auf leere (NULL-) Felder. Es kann verlockend sein zu prüfen, ob ein Feld leer ist, indem man die Operatoren = (gleich) oder != (ungleich) verwendet, um zu sehen, ob das Ergebnis gleich null ist. Empfohlen wird jedoch die Verwendung der integrierten Funktion ISBLANK(). ISBLANK() verwendet ein beliebiges Feld als Argument und gibt TRUE, falls das Feld leer ist, und andernfalls FALSE zurück. Wenn Sie eine Formel erstellen, können Sie leere Felder entweder als Nullen oder Leerzeichen behandeln. Standardmäßig ist Leere Felder als Nullen behandeln ausgewählt. Sie können ISBLANK() nur dann zum Prüfen, ob ein Feld leer ist, verwenden, wenn Leere Felder als leer behandeln aktiviert ist.